Aradığınız belgeyi buradan bulabilirsiniz.

Kılavuzlar

Dili baştan öğrenmek istiyorsanız belgeler yerine Öğren sayfasından başlamanızı öneririz.

Hızlı başvuru

Aşağıdaki program dilin en sık kullanılan yapılarını bir arada gösterir: sabit, kayıt tipi, tipli liste ve sözlük, fonksiyon, döngüler, koşul ve hata yakalama. Program olduğu gibi çalışır.

program HızlıBaşvuru
sabit
  SINIR: tamsayı = 5

tip
  Nokta = kayıt
    x, y: ondalık
  bitir

değişken
  toplam: tamsayı
  adlar: metin listesi
  yaşlar: tamsayı sözlüğü
  n: Nokta

fonksiyon Küp(k: tamsayı): tamsayı
başla
  dön k * k * k
bitir

başla
  toplam := 0
  1'den SINIR'a kadar her i için
    toplam := toplam + Küp(i)
  yaz('Toplam: ' + toplam, 1)

  adlar := ['Ada', 'Can', 'Ece']
  adlar içindeki her ad için
    eğer Uzunluk(ad) > 2 ise
      yaz(ad, 1)

  yaşlar := ['Ada': 12, 'Can': 14]
  yaşlar içindeki her ad, yaş için
    yaz(ad + ': ' + yaş, 1)
  toplam := 3
  toplam > 0 iken
    toplam := toplam - 1

  n.x := 3.0
  n.y := 4.0
  yaz(Kök(n.x * n.x + n.y * n.y), 1)

  dene
    yaz(10 böl 0, 1)
  yakala (h)
    yaz('Yakalandı: ' + h.mesaj, 1)
  bitir
bitir.

Döngüler

Sayan döngünün dört yazımı vardır. Adımı yazmadığınızda sayaç birer birer ilerler; adımı kendiniz belirlemek istediğinizde adımda sözcüğünü, ardından da yönü gösteren artan ya da azalan sözcüğünü kullanabilirsiniz.

program Döngüler
değişken
  n, adım: tamsayı
başla
  { birer birer artar }
  1'den 5'e kadar her i için yaz(i + ' ')
  yaz('', 1)

  { iki sınır da sayı olarak yazıldığında ve ilki büyükse birer birer azalır }
  5'ten 1'e kadar her j için yaz(j + ' ')
  yaz('', 1)

  { adımı siz belirlersiniz: artan }
  n := 10
  adım := 2
  0'dan n'ye adımda adım artan her k için yaz(k + ' ')
  yaz('', 1)

  { adımı siz belirlersiniz: azalan }
  n'den 0'a adımda 3 azalan her u için yaz(u + ' ')
  yaz('', 1)
bitir.

Tipler

Dosyanın başına {$katı} yazdığınızda derleyici tipleri program çalışmadan önce denetler ve bütün tip hatalarını bir arada listeler.

Liste ve sabit boyut

Sıralı elemanlar listede tutulur. Liste başlangıçta serbesttir: boyutu program çalışırken değişebilir ve elemanlar 0'dan numaralanır. Eleman sayısı baştan belliyse L.Uzunluk(n, ilk) ile boyutu sabitleyebilir ve numaralamayı istediğiniz sayıdan başlatabilirsiniz; L.Uzunluk(n) numaraları 0'dan başlatır. Yeni elemanlar tipin başlangıç değeriyle dolar, var olanlar korunur.

program ListeVeDizi
değişken
  notlar: tamsayı listesi
  aylar: tamsayı listesi
başla
  { liste: elemanlar 0'dan numaralanır, boyut değişebilir }
  notlar := [70, 85, 90, 60]
  Ekle(notlar, 100)        { sona ekler }
  Ekle(notlar, 75, 1)      { 75'i 1 numaralı konuma yerleştirir }
  notlar listesindeki 2. elemanı Sil
  yaz(notlar, 1)

  { Uzunluk(3, 1): 3 elemanlı, numaraları 1'den başlayan sabit boyutlu liste }
  aylar.Uzunluk(3, 1)
  aylar[1] := 31
  aylar[2] := 28
  aylar[3] := 31
  yaz(aylar, 1)

  { boyutu sabit listeden eleman çıkarmak gerektiğinde serbest bir kopya alınır }
  notlar := liste(aylar)
  Sil(notlar, 1)
  yaz(notlar, 1)
bitir.

Ekle iki biçimde kullanılır: Ekle(L, x) elemanı sona ekler, Ekle(L, x, konum) ise verilen konuma yerleştirir ve sonraki elemanları birer sıra kaydırır. Nokta ile de yazabilirsiniz: L.Ekle(x), L.Ekle(x, konum).

Bir elemanı silmenin üç yazımı vardır; üçü de aynı anlama gelir ve 2 numaralı elemanı (L[2]) siler:

L.Sil(2)
L(2).Sil
L listesindeki 2. elemanı Sil

Listede elemanlar 0'dan numaralandığı için 2 numaralı eleman baştan üçüncü sıradadır. Sil çıkardığı elemanı döndürür; eksi konum sondan sayar (L.Sil(-1) son elemanı siler). Cümle biçiminde hesaplanan konum ayraç içine yazılır: L listesindeki (i + 1). elemanı Sil.

Komutlar

Komutların ayrıntılarını Birimler ve Araçlar Kılavuzu'nun "Araçlar" bölümünde bulabilirsiniz.

Birimler

Birimler kullan ile programa eklenir. Aşağıdakilerin hepsi Yöntem ile birlikte gelir.